COMMENT ⊗   VALID 00002 PAGES
C REC  PAGE   DESCRIPTION
C00001 00001
C00002 00002	TITLE MAGDMP LOAD WAITS.DMP FROM MTA0
C00004 ENDMK
C⊗;
TITLE MAGDMP LOAD WAITS.DMP FROM MTA0

;COPY MTA:/DEN=800←WAITS.DMP

DEBSW←←0

A←1
B←2
C←3
D←4
E←5

APR←←0
DC←←204
MTC←←220
MTS←←224
MTM←←230

IFN DEBSW,<
	LOC 74
	JRST DDT↑
	LOC 200
	JRST MAGDMP
	JRST DDT
	LOC 100000
>;IFN DEBSW
IFE DEBSW,<
	LOC 200
>;IFE DEBSW

MAGDMP:	CONO APR,200000		;I/O RESET
IFE DEBSW,<
	MOVE A,[MAGGO,,777000]
	BLT A,777777
	JRST 777000
	LIT
	VAR
MAGGO:
	PHASE 777000
>;IFE DEBSW
	CONO MTC,060400		;REWIND
	CONSZ MTS,20000		;WAIT FOR REWIND TO FINISH
	JRST .-1
IFE DEBSW,<
	SETZM 20
	MOVE A,[20,,21]
	BLT A,777000-1		;CLEAR CORE
>;IFE DEBSW
IFN DEBSW,<
	SETZM 300
	MOVE A,[300,,301]
	BLT A,MAGDMP-1
>;IFN DEBSW
	CONO DC,4020		;GET DC READY FOR INPUT
	MOVEI A,74-1		;∞ BLKI STARTING AT 73
	MOVEM A,DCBLKI
LOOPR:	CONSO MTS,40000		;WAIT FOR TRANSFER NEXT COMMAND
	JRST .-1
	CONO MTC,062400		;TELL MAGTAPE TO READ
LOOP:	CONSO DC,1000		;DB RQ?
	JRST NODCRQ
	BLKI DC,DCBLKI
	JRST 4,.		;∞ BLKI CAN'T RUN OUT
	JRST LOOP

NODCRQ:	CONSO MTS,4		;EOR?
	JRST LOOP
	CONSZ MTS,400		;EOF?
	JRST SYMGO		;START UP SYSTEM
	JRST LOOPR

SYMGO:	MOVEI A,-1
	MOVEM A,37
	MOVE A,116
	MOVEM A,36
	HRRZ A,120		;JOBSA
	JRST (A)

DCBLKI:	0
	END MAGDMP